                             org 4082h          
4082 55..                    defs 7fh,55h         ; filler of $55 x 127, untouched by code
               bitmap:                            ; Prefix the code with the bitmap data
4101 fdaecf8df6fb6db6        defb fdh,aeh,cfh,8dh,f6h,fbh,6dh,b6h
               start:                             
4109 c5                      push bc              ; At startup “start” is in BC, so C = 9
410a e1                      pop hl               ; copy BC to HL, use as bitmap pointer
               col:     
410b 0609                    ld b, 9              ; start each col on the 9th row, and first
               rotate:                            ; plot 4 asterisks
410d e5                      push hl              ; save HL as it gets used to print
410e c5                      push bc              ; save BC as it gets destroyed 
410f cdf508                  call 08f5h           ; point HL at (col C, row B)
4112 c1                      pop bc               ; retrieve BC
4113 3e12                    ld a, 18             ; load rotation constant
4115 be                      cp (hl)              ; use it to check if all 4 plots are done
4116 3617                    ld (hl), 23          ; plot a *
4118 e1                      pop hl               ; retrieve HL
4119 3806                    jr c, xloop          ; if all 4 plots already done, x-it the loop
411b 90                      sub b                ; otherwise A = 18-B
411c 41                      ld b,c               ; B = C and
411d 4f                      ld c,a               ; C = 18-B => rotate 90º clockwise
411e c8                      ret z                ; If col = 0 then exit
               check:     
411f 30ec                    jr nc, rotate        ; if bit clear then plot it
               xloop:    
4121 cb3e                    srl (hl)             ; grab 1 bit from bitmap
4123 10fa                    djnz check           ; use this bit for next row, until we run out
4125 0d                      dec c                ; otherwise, move on to next col
4126 2b                      dec hl               ; iterate bitmap pointer
4127 18e2                    jr col               ; print the next col and its rotations
               end:    
4129